vopl ;BMI/BI VistA Option Viewer. ;11/20/2023
 Quit
 ;
list   ;public
 New name Set name=""
 Write "  <table>",!
 For x=1:1 Set name=$Order(^DIC(19,"B",name)) Quit:name=""  Do list1(name)
 Write "  </table>",!
 Quit
list1(name)
 New ien Set ien=0
 For  Set ien=$Order(^DIC(19,"B",name,ien)) Quit:+ien=0  Do list2(name,ien)
 Quit
list2(name,ien)
 Write "    <tr><td><a href=""vopl.php?fn=main&ien="_ien_""" target=""main"">"_name_"</a></td></tr>",!
 Quit
 ;
main   ;public 
 New ien,fda,FDA,dline,fieldname,iens
 Set ien=$zcmdline Quit:'ien
 If $Data(^DIC(19,ien))=0 Write "File Does Not Exist",! Quit
 Do loadfda(ien,.fda,.FDA)
 Write "<table>",!
 Write "<tr><td>NAME</td><td>"_fda("NAME")_"</td></tr>",!
 Write "<tr><td>DESCRIPTION</td><td>"
 Set dline=0 For  Set dline=$Order(fda("DESCRIPTION",dline)) Quit:+dline=0  Do
 . Write fda("DESCRIPTION",dline)
 Write "</td></tr>",!
 Set fieldname="" For  Do  Quit:fieldname=""
 . Set fieldname=$Order(fda(fieldname)) Quit:fieldname=""
 . Quit:fieldname="NAME"
 . Quit:fieldname="DESCRIPTION"
 . Write:fda(fieldname)'="" "<tr><td>"_fieldname_"</td><td>"_fda(fieldname)_"</td></tr>",!
 If $Data(FDA(19.01)) Do
 . Write "<tr><td>MENU ITEM<br/>DESCRIPTION</td><td>"
 . Write "<table width=""100%"">"
 . Write "<tr><td>SYNONYM</td><td>ITEM</td><td>DISPLAY ORDER</td></tr>",!
 . Set iens="" For  Set iens=$Order(FDA(19.01,iens)) Quit:iens=""  Do
 .. Write "<tr>"
 .. Write "<td>"_$Get(FDA(19.01,iens,"SYNONYM"))_"</td>"
 .. Write "<td>"_$Get(FDA(19.01,iens,"ITEM"))_"</td>"
 .. Write "<td>"_$Get(FDA(19.01,iens,"DISPLAY ORDER"))_"</td>"
 .. Write "</tr>",!
 . Write "</table>"
 . Write "</td></tr>"
 . Kill FDA(19.01)
 Write "</table>",!
 Write "<pre>",!
 If $Data(FDA) zwr FDA
 Write "</pre>",!
 Quit
 ;
loadfda(ien,fda,FDA)
 Do GETS^DIQ(19,ien,"**","R","FDA")
 Merge fda=FDA(19,ien_",")
 Kill FDA(19,ien_",")
 Quit