fmapil
 Quit
 ;
en
 New request,array
 Set request=$zcmdline Quit:request=""
 Set request=$$convert(request)
 Do DECODE^XLFJSON("request","array")
 If array("FUNCTION")="GETS" Do GETS(.array) Quit
 If array("FUNCTION")="GET1" Do GET1(.array) Quit
 If array("FUNCTION")="FINDDIC" Do FINDDIC(.array) Quit
 Do FUNCTIONNA
 Quit
 ;
GETS(ARRAY)
 New FILE,IENS,FIELD,FLAGS,FDA,ERR
 Set FILE=$Get(ARRAY("FILE")) Quit:FILE=""
 Set IENS=$Get(ARRAY("IENS")) Quit:IENS=""
 Set FIELD=$Get(ARRAY("FIELD")) Set:FIELD="" FIELD="**"
 Set FLAGS=$Get(ARRAY("FLAGS"))
 Write "<a href=""http://www.hardhats.org/fileman/pm/db_diqgs.htm"" target=""_blank"">http://www.hardhats.org/fileman/pm/db_diqgs.htm</a>",!
 Write "D GETS^DIQ("_FILE_","""_IENS_""","""_FIELD_""","""_FLAGS_""","_"""FDA"") ZWR FDA",!
 Write "<hr>",!
 Set $ETRAP="Goto GETSQUIT^fmapil"
 Do GETS^DIQ(FILE,IENS,FIELD,FLAGS,"FDA","ERR")
 Goto:$D(ERR) GETSQUIT
 If $D(FDA) ZWR FDA
GETSQUIT
 Set $ETRAP=""
 Quit
 ;
GET1(ARRAY)
 New FILE,IENS,FIELD,FLAGS,FDA
 Set FILE=$Get(ARRAY("FILE")) Quit:FILE=""
 Set IENS=$Get(ARRAY("IENS")) Quit:IENS=""
 Set FIELD=$Get(ARRAY("FIELD")) Set:FIELD="" FIELD="**"
 Set FLAGS=$Get(ARRAY("FLAGS"))
 Write "<a href=""http://www.hardhats.org/fileman/pm/db_diqg1.htm"" target=""_blank"">http://www.hardhats.org/fileman/pm/db_diqg1.htm</a>",!
 Write "S FDA=$$GET1^DIQ("_FILE_","""_IENS_""","""_FIELD_""","""_FLAGS_""") W FDA",!
 Write "<hr>",!
 Set FDA=$$GET1^DIQ(FILE,IENS,FIELD,FLAGS)
 Write FDA,!
 Quit
 ;
FINDDIC(ARRAY)
 New FILE,IENS,FIELD,FLAGS,VALUE,NUMBER,FDA
 Set FILE=$Get(ARRAY("FILE")) Quit:FILE=""
 Set IENS=$Get(ARRAY("IENS"))
 Set FIELD=$Get(ARRAY("FIELD"))
 Set FLAGS=$Get(ARRAY("FLAGS"))
 Set VALUE=$Get(ARRAY("VALUE"))
 Set NUMBER=$Get(ARRAY("NUMBER"))
 Write "<a href=""http://www.hardhats.org/fileman/pm/db_dicf.htm"" target=""_blank"">http://www.hardhats.org/fileman/pm/db_dicf.htm</a>",!
 Write "D FIND^DIC("_FILE_","""_IENS_""","""_FIELD_""","""_FLAGS_""","""_VALUE_""","""_NUMBER_""",,,,""FDA"") ZWR FDA",!
 Write "<hr>",!
 Do FIND^DIC(FILE,IENS,FIELD,FLAGS,.VALUE,NUMBER,,,,"FDA")
 If $Data(FDA) ZWR FDA
 Quit
 ;
FUNCTIONNA
 Write "That Function isn't available.",!
 Quit
 ;
convert(x)
 New y,z Set z=""
 For y=1:1:$Length(x,"%") Do
 . Set %HD=$Extract($Piece(x,"%",y),1,2) Do ^%HD
 . Set z=z_$C(%HD)_$Extract($Piece(x,"%",y),3,99)
 Quit $Translate(z,$c(13)_$c(10),"")